0 GOTO5
1 GOTO!!!!
2 REM
3 REM ZEILEN 0 UND 1 NICHT AENDERN !!!!
4 REM
5 DIMV$(14),H$(21),RI$(19),ZI$(19),G$(12),G(12)
6 L$="                        "
7 CL$="[165]                      [167]"
8 EF$="                                       "
10 POKE53280,14:POKE53281,14:POKE53272,23:P=15:QQ=54272:VI=53248
15 POKEVI+21,0:PRINT"[147]"SPC(12)"[144][195][193][211][212][204][197][160][207][198][160][196][207][207][205]":REM CASTLE OF DOOM
20 PRINT"    [197]IN [193]DVENTURE VON [194].[215]EISSBECKER"
25 PRINTSPC(11)"* [194]ITTE WARTEN *"
30 FORI=1TO14:READV$(I)
35 IFI<10THENREADKB$(I)
40 NEXT
45 FORI=1TO21:READH$(I):NEXT
50 FORI=1TO19:READRI$(I),ZI$(I):NEXT
55 FORI=1TO12:G$(I)=H$(I):READG(I):NEXT
60 FORI=1TO4:READZX$(I),ZY$(I):NEXT
65 FORI=13TO15
70 FORJ=0TO62:READK:POKE64*I+J,K:NEXT:NEXT
85 PRINT"[145]  [205]OECHTEN [211]IE EINE [197]RKLAERUNG ? ([202]/[206])"
90 GETA$:IFA$="J"THEN7500
95 IFA$<>"N"THEN90
100 PRINT"[147][144]"SPC(10)"[195][193][211][212][204][197][160][207][198][160][196][207][207][205]"
105 PRINT"[159] [194]EI DIESEM [193]DVENTURE KOENNEN [211]IE ZWI-"
110 PRINT" SCHEN DREI [214]ERSIONEN WAEHLEN :":PRINT"  [215]OLLEN [211]IE :"
115 PRINT"  1 - [197]INE VERZAUBERTE [208]RINZESSIN":PRINTSPC(6)"RETTEN"
120 PRINT"  2 - [197]INEN BOESEN [218]AUBERER BESIEGEN"
125 PRINT"  3 - [197]INEN [211]CHATZ SUCHEN"
130 PRINT" [194]ITTE GEBEN [211]IE DIE ENTSPRECHENDE"
135 PRINT" [203]ENNZIFFER EIN."
140 POKE198,0:WAIT198,1
145 GETI$:IFASC(I$)<49ORASC(I$)>51THEN140
150 V=VAL(I$):IFV<>2THEN160
155 RI$(13)="W-O":ZI$(13)="1214":RI$(9)="W-O-R":ZI$(9)="081018"
157 RI$(8)="N-S-O":ZI$(8)="051209"
160 IFV=1THENG(7)=1
165 FORI=1TO4:J(I)=1+4*RND(TI):NEXT
170 Z1$=ZX$(J(1))+ZY$(J(2))
175 Z2$=ZX$(J(3))+ZY$(J(4))
176 IFZ1$=Z2$THEN165
177 TI$="000000"
179 REM **** BILDER ZEICHNEN ****
180 PRINT"[147][144]";:POKE53272,21:POKEVI+21,0:POKEVI+23,0:POKEVI+29,0
185 FORI=1TO20:PRINTSPC(8)CL$:NEXT
190 FORI=1824TO1863:POKEI,99:POKEI+QQ,0:NEXT
195 IFP>11THEN415
197 POKE53280,5:POKE53281,5
200 PRINT"";:FORI=1TO4:PRINTSPC(8+I)"[205]"SPC(22-2*I)"[206]":NEXT
205 PRINTSPC(13)"[145][175][175][175][175][175][175][175][175][175][175][175][175][175][175]"
210 FORI=1TO10:PRINTSPC(12)"[167]"SPC(14)"[165]":NEXT
215 PRINTSPC(13)"[183][183][183][183][183][183][183][183][183][183][183][183][183][183][145]"
220 FORI=1TO5:PRINTSPC(13-I)"[206]"SPC(12+2*I)"[205]":NEXT
225 FORI=1TOLEN(RI$(P))STEP2:A$=MID$(RI$(P),I,1)
230 IFA$="N"THEN250
235 IFA$="W"THEN260
240 IFA$="O"THEN265
245 NEXT:GOTO270
250 FORJ=1402TO1562STEP40:FORK=0TO3:POKEJ+K,160:POKEJ+K+QQ,0:NEXT:NEXT
255 POKE1402,254:POKE1405,252:GOTO245
260 FORJ=1552TO1752STEP40:POKEJ,160:POKEQQ+J,0:NEXT:POKE1752,105:GOTO245
265 FORJ=1575TO1775STEP40:POKEJ,160:POKEQQ+J,0:NEXT:POKE1775,95:GOTO245
270 ONPGOTO275,740,300,315,740,325,345,740,355,375,395
275 ONVGOTO740,280,285
280 POKE2040,15:POKEVI+39,0:POKEVI,150:POKEVI+1,140:POKEVI+29,1:POKEVI+23,1
282 POKEVI+21,1:ZB=1:GOTO740
285 PRINT""SPC(13)"[175][175][175][175]":PRINTSPC(12)"[206]   [206][180]"
290 PRINTSPC(11)"[206]   [206] [180]":PRINTSPC(11)"[207][183][183][208]  [180]":PRINTSPC(11)"[180]$$[170] [206]"
295 PRINTSPC(11)"[204][175][175][186][206] SCHATZ":FORI=1TO2000:NEXT:GOTO7830
300 IFLEFT$(RI$(3),1)="N"THEN740
305 FORJ=1402TO1562STEP40:FORK=0TO3
310 POKEJ+K,160:POKEJ+K+QQ,06:NEXT:NEXT:PRINTSPC(16)"[145][145][145][145][144]SPIEGEL":GOTO740
315 PRINT""SPC(13)"[223]    [146][169]":PRINTSPC(14)"[223]  [146][169]":PRINTSPC(15)"[180][170]"
320 FORI=1TO10:PRINTSPC(15)"[207][208]":NEXT:GOTO740
325 PRINT"[149]"SPC(13)"[175][175][175][175][175]":PRINTSPC(13)"[204][175][175][175][186]"
330 PRINTSPC(12)"[206]    [206][180]":PRINTSPC(11)"[206]    [206][206][180]":PRINTSPC(10)"[206]    [206][206][183]"
335 PRINTSPC(9)"[207][183][183][183][208][206][206]":PRINTSPC(9)"[180]   [170][206]":PRINTSPC(9)"[204][175][175][175][186]  SCHLAFZIMMER"
340 GOTO740
345 IFGE=1THEN740
350 POKE2040,13:POKEVI+39,1:POKEVI,150:POKEVI+1,150:POKEVI+23,1:POKEVI+29,1
351 POKEVI+21,1:IFG(12)<>0THENFORI=1TO2000:NEXT:GOTO7630
352 GS=1:GOTO740
355 PRINT"[144]"SPC(11)"BURGHOF / BRUNNEN":PRINTSPC(13)"[207][204][207][204][207][204][207][208][186][208][186][208][186][208]"
360 PRINTSPC(17)"[164][175][185][185][175][164]":PRINTSPC(16)"        "
365 PRINTSPC(16)"[180][163][183][184][184][183][163][170]":PRINTSPC(16)"[180]      [170]":PRINTSPC(16)"[183][197][196][195][195][196][197][183]"
370 GOTO740
375 POKE214,14:PRINT
380 IFFA=1THENPRINTSPC(23)"[223]   [223]":PRINTSPC(24)"[223]   [223]":GOTO740
385 PRINTSPC(23)"[175][175][175][175]":PRINTSPC(23)"[205]   [205]"
390 PRINTSPC(16)"QUADRAT [205]   [205]":PRINTSPC(25)"[183][183][183][183]":GOTO740
395 PRINT""SPC(23)"[175][175][175][175]":PRINTSPC(22)"[170][205]   [205]":PRINTSPC(22)"[170] [207][208][183][208]"
400 PRINTSPC(15)"[204][186]     [170] [180][170].[170]":PRINTSPC(15)"[204][186]     [170] [180][170] [170]"
405 PRINTSPC(14)"[169]  [223][146][183][183][183][183][183][205][204][186][175][186]":PRINTSPC(13)"[169]    [223]"
410 PRINTSPC(21)"SCHRANK":GOTO740
415 IFP>14THEN445
417 POKE53280,8:POKE53281,8
420 PRINT"";:FORI=1TO6:PRINTSPC(8)""L$:NEXT
425 FORI=55504TO55514STEP2:POKEI,7:NEXT:FORI=55517TO55527STEP2:POKEI,7:NEXT
430 FORI=1TO11:PRINT"[158]"SPC(8)L$:NEXT:FORI=1TO3:PRINT"[149]"SPC(8)L$:NEXT
435 IFLEFT$(RI$(P),1)<>"N"THEN740
440 POKE214,11:PRINT"[144]":FORI=1TO5:PRINTSPC(18)"    ":NEXT
442 GOTO740
445 POKE53280,14:POKE53281,14:ONP-14GOTO555,450,485,500,540
450 PRINT"[158]"SPC(20)"[172]":PRINTSPC(18)"   "
460 PRINTSPC(17)"[149][172] [206] [188]":PRINTSPC(16)"[169] [206]   [188]"
465 PRINTSPC(15)"[172] (      [188]":PRINTSPC(14)"[162][190]  [205]       [188]"
470 PRINTSPC(13)"[169]     [205]       [188]"
475 FORI=1TO7:PRINTSPC(8)L$:NEXT
480 PRINTSPC(9)"[145][145][145][145][145][145]BERG"
481 IFLEN(RI$(16))=5THENPRINTSPC(9)"STEILER WEG NACH OBEN"
482 GOTO740
485 PRINT""SPC(9)"STEILER BERGHANG,":PRINTSPC(9)"HOEHLE"
490 PRINTSPC(21)"[162]":PRINTSPC(19)"[172]   [190][188][146][187]"
495 FORI=1TO6:PRINTSPC(19)"       ":NEXT:GOTO740
500 PRINT"";:FORI=1TO19:PRINTSPC(8)L$:NEXT
505 PRINT""SPC(9)"IM BRUNNEN ..."
510 IFV<>3THEN740
515 IFMO=1THENPRINT"":GOTO530
520 POKE2040,14:POKEVI+39,13:POKEVI,200:POKEVI+1,150:POKEVI+23,1:POKEVI+29,1
525 PRINTSPC(9)"MONSTER":POKEVI+21,1:MR=1
530 PRINTSPC(9)"TUER":FORI=1TO7:PRINTSPC(16)"     ":NEXT
535 IFRI$(18)="H"THENPOKE1601,114
537 GOTO740
540 PRINT"";:FORI=1TO20:PRINTSPC(8)L$:NEXT
545 PRINT""SPC(9)"IN DER HOEHLE ..."
550 PRINTSPC(9)"STOCKDUNKEL HIER ...":GOTO740
555 PRINT""SPC(13)"[207][183][183][183][183][183][183][183][183][183][183][183][208]":PRINTSPC(13)"[180] B A S A R [170]"
560 PRINTSPC(13)"[204][175][175][175][175][175][175][175][175][175][175][175][186]"
565 IFXX=1THEN655
570 PRINTSPC(9)"[144]EIN   BEFREUNDETER"
575 PRINTSPC(9)"HAENDLER IST BEREIT,":PRINTSPC(9)"IHNEN ZWEI DER FOLGEN-"
580 PRINTSPC(9)"DEN GEGENSTAENDE ZU":PRINTSPC(9)"UEBERLASSEN :"
585 PRINTSPC(9)"1[146] GLASKUGEL 2[146] KAEFIG"
590 PRINTSPC(9)"3[146] AMULETT   4[146] BUCH"
595 PRINT"  BITTE ENTSPRECHENDE NUMMERN EINGEBEN"
600 GETI$:IFI$=""THEN600
605 IFASC(I$)<49ORASC(I$)>52THEN600
610 ONVAL(I$)GOSUB635,640,645,650
615 GETJ$:IFJ$=""ORJ$=I$THEN615
620 IFASC(J$)<49ORASC(J$)>52THEN615
625 ONVAL(J$)GOSUB635,640,645,650
630 XX=1:GG=GG+2:GOSUB7000:GOTO655
635 POKE1633,49:G(1)=0:RETURN
640 POKE1645,50:G(2)=0:RETURN
645 POKE1713,51:G(3)=0:RETURN
650 POKE1725,52:G(4)=0:RETURN
655 YY=0:FORI=1TO4:IFG(I)=0THENYY=YY+1
657 NEXT:IFYY<>2THEN710
660 PRINT"[144]"SPC(9)"WOLLEN SIE DIE GEGEN-"
665 PRINTSPC(9)"STAENDE, DIE SIE HIER":PRINTSPC(9)"ERHALTEN HABEN, NOCH  "
670 PRINTSPC(9)"EINMAL UMTAUSCHEN ?":PRINTSPC(9)"        (J/N)"
675 PRINT:PRINTSPC(8)CL$:PRINT:PRINTSPC(8)CL$:GOSUB860
680 GETI$:IFI$="N"THEN710
685 IFI$<>"J"THEN680
690 FORI=1TO4:G(I)=20:NEXT:GG=GG-2
695 PRINT"":FORI=1TO9:PRINTSPC(8)CL$:NEXT
700 PRINT""SPC(12)"WAEHLEN SIE !":PRINT""
705 GOTO585
710 PRINT"[144]":FORI=1TO9:PRINTSPC(8)CL$:NEXT
715 PRINT"":FORI=1TO5:PRINTSPC(13)"[181]"SPC(11)"[182]":NEXT
720 PRINTSPC(13)"[159][207][183][183][183][183][183][183][183][183][183][183][183][208]":PRINTSPC(13)"[180][207][183][208] [207][183][208] [207][183][208][170]"
725 PRINTSPC(13)"[180][180][209][159][170] [180][209][159][170] [180][209][159][170][170]"
730 PRINTSPC(13)"[180][204][175][186] [204][175][186] [204][175][186][170]":PRINTSPC(13)"[204][175][175][175][175][175][175][175][175][175][175][175][186]"
740 POKE214,18:PRINT:PRINTSPC(9)"[144]RICHTUNGEN : "RI$(P):GOTO750
748 REM **** KOMMANDOAUSWERTUNG ****
749 FORI=1TO2500:NEXT
750 ZA=0:GOSUB7000
755 GOSUB860:INPUT"[158] KOMMANDO :";K$
760 IFLEFT$(K$,1)=" "THENK$=RIGHT$(K$,LEN(K$)-1):GOTO760
765 IFLEN(K$)=1THEN870
770 FORI=1TOLEN(K$):IFMID$(K$,I,1)=" "THEN780
772 NEXT
775 GOSUB860:PRINT"          UNKORREKTE EINGABE !":GOTO749
780 V$=LEFT$(K$,I-1):H$=RIGHT$(K$,LEN(K$)-I)
785 IFLEFT$(H$,1)=" "THENH$=RIGHT$(H$,LEN(H$)-1):GOTO785
790 IFV$="SAGE"THEN6500
795 FORI=1TO14:IFLEFT$(V$(I),LEN(V$))=V$THENX=I:GOTO805
800 NEXT:NV$=V$:GOTO815
805 FORI=1TO21:IFLEFT$(H$(I),LEN(H$))=H$THENY=I:GOTO825
810 NEXT:NV$=H$
815 GOSUB860:PRINT"[145] TUT MIR LEID, ABER ICH VERSTEHE"
820 PRINT" '"NV$"' NICHT.":GOTO749
825 IFX>9THENX=X-5
830 FORI=1TOLEN(KB$(X)):IFMID$(KB$(X),I,1)=CHR$(Y+64)THEN950
835 NEXT:GOSUB860
840 PRINT"[145] TUT MIR LEID, ABER ICH VERSTEHE IHREN"
845 PRINT" BEFEHL NICHT.":GOTO749
860 POKE214,20:PRINT:FORI=1TO3:PRINTEF$:NEXT:PRINT"[145][145][145]":RETURN
869 REM **** BEWEGEN ****
870 FORI=1TO6:IFK$=MID$("NSWOHR",I,1)THEN880
875 NEXT:GOTO775
880 IFGS=1ORZB=1ORMR=1THEN7600
882 FORI=1TOLEN(RI$(P))STEP2
885 IFMID$(RI$(P),I,1)=K$THEN900
890 NEXT:GOSUB860
895 PRINT"   IN DIESE RICHTUNG GEHT ES NICHT":GOTO749
900 SC=0:ZI=VAL(MID$(ZI$(P),I,2))
905 IFP=16ANDZI=13THEN925
910 IFP=13ANDZI=9ANDG(8)=0ANDV=1THEN7660
915 IFZI=0THEN7680
920 P=ZI:GOTO180
925 IFG(8)=0THENONVGOTO930,7650,7670
930 GOSUB860:PRINT"[145] HINTER IHNEN LOEST SICH EINE STEIN-"
935 PRINT" LAWINE, DIE DEN WEG VERSCHUETTET.":RI$(16)="W-O":ZI$(16)="1517"
940 FORI=1TO2500:NEXT:P=ZI:GOTO180
949 REM ** SPRUNG ZUR BEF.AUSFUEHRUNG **
950 IFX=4ANDY<13THEN7100
955 IFX=5THEN7200
960 ZN=1000+(X-1)*500+(Y-1)*20:ZN$=STR$(ZN)
965 FORI=1TO4:NZ=VAL(MID$(ZN$,I+1,1))
970 POKE(2060+I),(NZ+48)
975 NEXT
980 GOSUB860:GOTO1
998 REM *** BEFEHLSAUSFUEHRUNG ***
999 PRINT"  OK !":GOTO749
1000 IFY=1ORY=7ORY=16ORY=19ORY=20THENE$="E ":GOTO1002
1001 E$=" "
1002 PRINT" HIER IST KEIN"E$H$(Y):GOTO749
1020 IFG(Y)=0ORG(Y)=PTHEN999
1022 GOTO1000
1060 GOTO1020
1180 IFG(10)<>0ANDG(10)<>PTHEN1000
1182 IFV<>2THENPRINT" DER "H$(10)" LAESST SICH NICHT OEFFNEN":GOTO749
1184 IFG(9)<>21THEN999
1186 PRINT" IM "H$(10)" BEFINDET SICH EIN "H$(9)" !!":G(9)=P:GOTO749
1300 IFP=18ANDRI$(18)="H"ANDV=3THEN1306
1302 IFP=1ORP>13THEN1000
1304 PRINT" HIER IST KEINE GESCHLOSSENE TUER":GOTO749
1306 IFG(11)<>0THENPRINT" DIE TUER IST VERSCHLOSSEN !":GOTO749
1308 RI$(18)="O-H":ZI$(18)="1909":RI$(19)="S-W":ZI$(19)="1718":GOTO180
1340 IFP<>11THEN1000
1342 IFV=3ORG(10)<>21THEN999
1344 IFG(11)<>0THENPRINT" DER SCHRANK IST VERSCHLOSSEN":GOTO749
1346 PRINT"[145]   IM SCHRANK BEFINDET SICH"
1348 PRINT"   EIN GOLDENER BALL":G(10)=11:GOTO749
1400 PRINT" DAS IST UNMOEGLICH !":GOTO749
1580 IFG(5)<>PTHEN1000
1582 IFP=18THENPRINT" ES IST ZU DUNKEL HIER !":GOTO749
1584 IFG(2)=0THEN1590
1586 PRINT"[145] SIE BRAUCHEN EINEN BEHAELTER"
1588 PRINT" UM DEN FROSCH ZU FANGEN !":GOTO749
1590 IFGG=5THENPRINT" SIE TRAGEN SCHON 5 GEGENSTAENDE !":GOTO749
1592 G(5)=0:GG=GG+1:PRINT" OK !":GOTO749
1740 IFMR=1THEN7640
1742 IFV=3ANDP=9ANDMO=0THENPRINT" VON HIER AUS GEHT DAS NICHT !":GOTO749
1744 GOTO1000
1780 IFGS<>1THEN1000
1782 PRINT"  DER GEIST MAG DAS NICHT !!":FORI=1TO2000:NEXT:GOTO7630
2080 IFG(5)=PTHENPRINT" DER FROSCH LAESST SICH NICHT KUESSEN":GOTO749
2082 IFG(5)<>0THEN1000
2084 IFV<>1ORP<>6THEN999
2086 PRINT" ES KNALLT UND STINKT...":FORI=1TO2000:NEXT:GOTO7800
2240 IFMR<>1THEN1000
2242 PRINT"[145] DAS MONSTER SCHLAEGT WILD UM SICH"
2244 PRINT" UND SCHLEUDERT SIE AUS DEM BRUNNEN":MR=0
2246 FORI=1TO3000:NEXT:P=9:GOTO180
2260 IFZB<>1THEN1000
2262 FORI=0TO15:POKE53281,I:POKE53280,I:FORJ=1TO100:NEXT:NEXT:ZB=0
2264 POKE53280,5:POKE53281,5:ZK=ZK+1:IFZK=3THEN7620
2266 P=2+INT(13*RND(TI)):GOTO180
2280 IFGS<>1THEN1000
2282 IFTI$<"001000"THEN7630
2284 GE=1:GS=0:FORI=832TO892STEP3:POKEI,0:POKEI+1,0:POKEI+2,0:NEXT
2286 PRINT"[145]  DER GEIST HAT IHREN MUNDGERUCH":PRINT"  NICHT VERTRAGEN !"
2288 GOTO749
2400 IFP<>10ORFA=1THEN1000
2402 IFV<>1THEN999
2404 IFV=1THENFA=1:RI$(10)="N-W-R":ZI$(10)="070919"
2406 RI$(19)="S-H":ZI$(19)="1710":GOTO180
2820 IFP<>3ORLEN(RI$(3))=5THEN1000
2822 PRINT" DAS GEHT NICHT !":GOTO749
2840 IFP<>11THEN1000
2842 PRINT" DER SCHRANK IST ZU SCHWER !":GOTO749
2900 IFP<>10ORFA=1THEN1000
2902 GOTO2822
3560 IFGS=1THEN7630
3562 IFG(4)<>0THENPRINT" ICH HABE DAS BUCH NICHT !":GOTO749
3564 IFV=3THEN3568
3566 PRINT" ZAUBERWORT : "Z1$:GOTO749
3568 PRINT"[145] ZAUBERWOERTER : "Z1$:PRINT""SPC(17)Z2$:GOTO749
3660 IFG(9)<>0THENPRINT" ICH HABE KEINEN ZETTEL":GOTO749
3662 PRINT" ZAUBERWORT: "Z2$:FORI=1TO2500:NEXT
3664 PRINT"[145] DER ZETTEL VERSCHWINDET !!!":GG=GG-1:G(9)=21:GOTO749
3860 IFP<>12ORSC=0THEN1000
3862 PRINT"[145]  TUT MIR LEID, ABER ES SCHEINT"
3864 PRINT"  EINE FREMDE SPRACHE ZU SEIN":GOTO749
4300 IFP<12OR(V=3ANDP=18)THENPRINT" OK...NICHTS PASSIERT !":GOTO749
4302 GOTO1000
4320 IFP<>3ORLEN(RI$(3))=5THEN1000
4322 PRINT"[145] HINTER DEM "H$(17)
4324 PRINT" SCHEINT EIN HOHLRAUM ZU SEIN !":GOTO749
4380 IFV=2ANDP=12ANDLEN(RI$(12))=3THEN4388
4382 IFP=19ANDG(8)=21THEN4392
4384 IFP>14ANDP<18THEN1000
4386 PRINT" OK...NICHTS BESONDERES FESTZUSTELLEN !":GOTO749
4388 POKE214,11:PRINT:PRINTSPC(18)"[158][213][171]/[215]":GOSUB860
4390 PRINT" EINE SCHRIFT ERSCHEINT...":SC=1:GOTO749
4392 G(8)=19:PRINT" AN DER WAND HAENGT EIN SCHWERT !":GOTO749
4400 IFP=10ANDFA=0THENPRINT" KLINGT HOHL...":GOTO749
4402 GOTO1000
4580 IFG(5)<>0ANDG(5)<>PTHEN1000
4582 PRINT" DER FROSCH ENTWISCHT IHNEN !"
4584 IFG(5)<>18ORV<>1THEN4588
4586 GOTO749
4588 IFG(5)=0THENGG=GG-1
4590 G(5)=1+INT(19*RND(1)):GOTO749
4740 IFMR=0THEN1000
4742 PRINT" GUTE IDEE, ABER DAS GEHT NICHT !":GOTO749
4760 IFZB=0THEN1000
4762 GOSUB4770:IFY=0ORG(Y)<>0THEN749
4764 IFY=8ANDZA=2THEN7820
4766 GOTO7620
4770 INPUT" WOMIT ";WM$
4771 FORI=1TOLEN(WM$):IFMID$(WM$,I,1)=" "THEN4773
4772 NEXT:GOTO4774
4773 WM$=RIGHT$(WM$,LEN(WM$)-I)
4774 FORY=1TO12:IFWM$=LEFT$(H$(Y),LEN(WM$))THEN4776
4775 NEXT:GOSUB860:PRINT" ICH VERSTEHE '"WM$"' NICHT !":Y=0:RETURN
4776 IFG(Y)<>0THENGOSUB860:PRINT" ICH HABE DIESEN GEGENSTAND NICHT !"
4777 RETURN
4780 IFGS=0THEN1000
4782 GOSUB4770:IFY=0ORG(Y)<>0THEN749
4784 GOSUB860:ONVGOTO4785,4790,4794
4785 IFG(8)=0THENPRINT" SIE SIND GESTOLPERT, UND...":FORI=1TO2000:NEXT:GOTO7630
4786 IFZA=1ANDY=7THEN4798
4788 GOTO7630
4790 IFZA=1ANDY=3THEN4798
4792 GOTO7630
4794 IFY=1THENPRINT" DER GEIST IST TOT, ABER...":FORI=1TO2000:NEXT
4796 GOTO7630
4798 POKEVI+21,0:GS=0:GE=1:PRINT" OK...DER GEIST IST TOT !":GOTO749
5000 IFG(1)<>0ANDG(1)<>PTHEN1000
5002 PRINT" WOZU SOLLTE DAS GUT SEIN ?":GOTO749
5020 IFG(2)<>0ANDG(2)<>PTHEN1000
5022 PRINT"[145] SO GEHT MAN NICHT MIT FREMDEM"
5024 PRINT" EIGENTUM UM !":GOTO749
5300 IFP=18ANDRI$(18)="H"ANDV=3THEN5306
5302 IFP=1ORP>13THEN1000
5304 PRINT"WIESO, HIER IST KEINE VERSCHLOSSENE TUER":GOTO749
5306 PRINT" DIE TUER IST ZU STABIL...":GOTO749
5320 GOSUB4770:IFY=0ORG(Y)<>0THEN749
5322 IF(V=1ANDY=8)OR(V=3ANDZA=2ANDY=8)THEN7247
5324 GOSUB860:PRINT" DAS GEHT NICHT !":GOTO749
5340 IFP<>11THEN1000
5342 PRINT"[145] DER SCHRANK LAESST SICH NICHT"
5344 PRINT" MIT GEWALT OEFFNEN !":GOTO749
5380 IFP>14ANDP<18THEN1000
5382 PRINT"SIE KOENNEN DIE WAND NICHT ZERSTOEREN !":GOTO749
6499 REM *** BEFEHL 'SAGE' ***
6500 GOSUB860:IFH$=Z1$THENZA=1:GOTO6506
6502 IFH$=Z2$THENZA=2:GOTO6506
6504 GOTO7690
6506 ONVGOTO6508,6512,6520
6508 IFZA=1ANDG(7)=0ANDGS=1ANDG(4)=0THENPRINT" DIE KEULE VIBRIERT...":GOTO6528
6510 GOTO6526
6512 IFZA=1ANDP=12ANDSC=1THENRI$(12)="N-W-O":ZI$(12)="080013":GOTO415
6514 IFZA=1ANDG(3)=0ANDGS=1THENPOKEVI+39,0:GOTO755
6516 IFZA=2ANDG(8)=0ANDZB=1ANDG(4)=0THENPRINT" DAS SCHWERT LEUCHTET...":GOTO6528
6518 GOTO6526
6520 IFZA=1ANDG(3)=0ANDMO=0ANDP=9THENPRINT" DAS AMULETT LEUCHTET...":GOTO6528
6522 IFZA<>2ORG(4)<>0ORP<>3ORRI$(3)<>"W-O"THEN6526
6524 PRINT" DER SPIEGEL LEUCHTET...":GOTO6528
6526 PRINT" OK...ES TUT SICH NICHTS !":GOTO749
6528 FORI=1TO2000:NEXT:GOTO755
6999 REM * BESITZ/GEGENSTD ANZEIGEN *
7000 PRINT"";:FORI=1TO20:PRINT"        ":NEXT
7002 PRINT"[144]SIE":PRINT"BESITZEN":SP=0
7005 FORI=1TO12:IFG(I)=0THENGOSUB7050
7010 NEXT
7020 PRINT"";:FORI=1TO20:PRINTSPC(32)"       ":NEXT
7022 J=0:PRINT"[144]"SPC(32)"ES GIBT":PRINTSPC(32)"HIER :":SP=32
7025 FORI=1TO12:IFG(I)=PTHENGOSUB7050:J=J+1:IFJ=6THENRETURN
7030 NEXT:RETURN
7050 IFI=1THENPRINTSPC(SP)"GLAS-":PRINTSPC(SP)"KUGEL":RETURN
7055 IFI=11THENPRINTSPC(SP)"SCHLUES":PRINTSPC(SP)"SEL":RETURN
7060 IFI=12THENPRINTSPC(SP)"KETTEN-":PRINTSPC(SP)"HEMD":RETURN
7065 PRINTSPC(SP)""G$(I):RETURN
7099 REM *** BEFEHL 'NIMM' ***
7100 IFG(Y)=PTHEN7110
7105 GOSUB860:PRINT"  DIESER GEGENSTAND IST NICHT HIER !":GOTO749
7110 IFGG<5THEN7120
7115 GOSUB860:PRINT"  SIE HABEN BEREITS 5 GEGENSTAENDE !":GOTO749
7120 IFY=5THENGOSUB860:PRINT"    DER FROSCH HUEPFT IHNEN DAVON !":GOTO749
7125 G(Y)=0:GG=GG+1:GOSUB860:PRINT"   OK !":FORI=1TO1000:NEXT:GOTO750
7199 REM *** BEFEHL 'WIRF' ***
7200 IFG(Y)<>0THENGOSUB860:PRINT" ICH HABE DIESEN GEGENSTAND NICHT !":GOTO749
7205 GOSUB860:INPUT"  WOHIN ";WH$
7210 FORI=1TOLEN(WH$):IFMID$(WH$,I,1)=" "THEN7220
7215 NEXT:GOTO7225
7220 WH$=RIGHT$(WH$,LEN(WH$)-I)
7225 IFWH$="BODEN"ORWH$="WEG"ORWH$="EGAL"ORWH$="WAND"THEN7235
7230 ONVGOTO7240,7270,7330
7235 GOSUB860:PRINT"  OK !":G(Y)=P:GG=GG-1:GOTO749
7240 IFY<>8ORWH$<>"SPIEGEL"ORP<>3ORLEN(RI$(3))=5THEN7255
7245 G(Y)=3:GG=GG-1
7247 RI$(3)="N-W-O":ZI$(3)="010204":GOSUB860
7250 PRINT"  DER SPIEGEL ZERBRICHT !":FORI=1TO2000:NEXT:GOTO180
7255 IFY<>10ORWH$<>"BRUNNEN"ORP<>9ORG(5)<>18THEN7380
7260 GOSUB860:PRINT"[145]  AUS DEM BRUNNEN KOMMT EIN FROSCH"
7265 PRINT"  MIT DEM BALL IM MUND.":G(10)=9:G(5)=9:GG=GG-1:GOTO749
7270 IFY<>3ORWH$<>"GEIST"ORGS<>1THEN7290
7275 IFZA<>1THEN7630
7280 POKEVI+21,0:GOSUB860:PRINT"    SIE HABEN DEN GEIST BESIEGT !"
7285 GE=1:GS=0:G(Y)=7:GG=GG-1:GOTO749
7290 IFY<>6ORP<>10ORWH$<>"QUADRAT"ORFA=1THEN7305
7295 FA=1:G(6)=10:GG=GG-1:RI$(10)="N-W-R":ZI$(10)="070919"
7300 RI$(19)="S-H":ZI$(19)="1710":GOTO180
7305 IFY<>4ORP<>3ORWH$<>"SPIEGEL"ORLEN(RI$(3))=5THEN7315
7310 GOTO7245
7315 IFY<>8ORZB<>1ORWH$<>"ZAUBERER"THEN7380
7320 IFZA<>2THEN7620
7325 POKEVI+21,0:FORI=1TO2000:NEXT:GOTO7820
7330 IFY<>1ORWH$<>"GEIST"ORGS<>1THEN7340
7335 GOTO7280
7340 IFY<>3ORWH$<>"BRUNNEN"ORP<>9THEN7360
7345 G(3)=18:GG=GG-1:GOSUB860:IFMO=1THENPRINT"  OK !":GOTO749
7350 IFZA=1THENPRINT" AUS DEM BRUNNEN ERTOENT EIN SCHREI...":MO=1:GOTO749
7355 G(3)=9:PRINT" DAS AMULETT KOMMT ZURUECKGEFLOGEN !":GOTO749
7360 IFY<>8ORWH$<>"SPIEGEL"ORP<>3ORLEN(RI$(3))=5THEN7380
7365 IFZA=2THEN7245
7370 GOTO7235
7380 IFWH$="BRUNNEN"ANDP=9THENG(Y)=18:GOTO7415
7382 IFWH$="QUADRAT"ANDP=10ANDFA=0THENG(Y)=10:GOTO7415
7385 IFWH$="HOEHLE"ANDP=17THENG(Y)=19:GOTO7415
7390 IFWH$="GEIST"ANDGS=1THEN7630
7395 IFWH$="ZAUBERER"ANDZB=1THEN7620
7400 IFWH$="SPIEGEL"ANDP=3ANDLEN(RI$(3))=3THEN7235
7405 GOSUB860:PRINT" ICH VERSTEHE SIE NICHT..."
7410 FORI=1TO2000:NEXT:GOTO7205
7415 GG=GG-1:GOSUB860:PRINT"  OK !":GOTO749
7499 REM *** ERKLAERUNG ***
7500 PRINT"[147] [211]IE MUESSEN VERSUCHEN, EINE [193]UFGABE ZU"
7505 PRINT" LOESEN, INDEM [211]IE DEM [195]OMPUTER SAGEN,"
7510 PRINT" WAS ER TUN SOLL."
7515 PRINT" [218]UR  [198]ORTBEWEGUNG  GEBEN  [211]IE NUR"
7520 PRINT" [193]BKUERZUNGEN EIN ([206]-[211]-[215]-[207]-[200]-[210] = [206][207][210][196] -":REM N-S-W-O-H-R = NORD -
7525 PRINT" [211][213][197][196] - [215][197][211][212] - [207][211][212] - [200][207][195][200] - [210][213][206][212][197][210])"
7526 REM SUED - WEST - OST - HOCH - RUNTER
7530 PRINT" [193]NSONSTEN MUESSEN DIE [194]EFEHLE AUS ZWEI"
7535 PRINT" [215]OERTERN BESTEHEN ([214]ERB/[200]AUPTWORT)"
7540 PRINT" [196]ER [195]OMPUTER VERSTEHT DIE [214]ERBEN :"
7545 PRINT" OEFFNE,FANGE,KUESSE,NIMM,LIES,WIRF,"
7550 PRINT" BERUEHRE/KLOPFE,ERSCHLAGE/TOETE,SAGE"
7555 PRINT" ZERBRECHE/ZERSTOERE   -  [198]ERTIG ???"
7560 POKE198,0:WAIT198,1:GOTO100
7599 REM **** VERLOREN ****
7600 IFZB=1THEN7620
7605 IFGS=1THEN7630
7610 IFMR=1THEN7640
7620 PRINT"[147][144] DER ZAUBERER HAT SIE IN EINE KROETE"
7625 PRINT" VERWANDELT.":GOTO7700
7630 PRINT"[147][144]     DER GEIST HAT SIE GEBISSEN.":GOTO7700
7640 PRINT"[147][144] DAS MONSTER HAT BESCHLOSSEN, SIE"
7645 PRINT" ZU HEIRATEN.":GOTO7700
7650 PRINT"[147][144] SIE SIND UNTERWEGS GESTOLPERT UND"
7655 PRINT" HABEN SICH DABEI DEN KLEINEN FINGER":PRINT" VERSTAUCHT.":GOTO7700
7660 PRINT"[147][144] AUS DEM TORBOGEN HAT SICH EIN STEIN"
7665 PRINT" GELOEST UND IST IHNEN AUF DEN FUSS":PRINT" GEFALLEN.":GOTO7700
7670 PRINT"[147][144] SIE SIND IN EINEN ERDRUTSCH GERATEN"
7675 PRINT" UND HABEN SICH IHRE NEUE HOSE DRECKIG":PRINT" GEMACHT.":GOTO7700
7680 PRINT"[147][144] SIE SIND VOM BERG GEFALLEN UND HABEN"
7685 PRINT" DABEI IHRE BRILLE ZERBROCHEN.":GOTO7700
7690 PRINT"[147][144]        SIE HABEN SICH IN EINE"
7695 PRINT"          BANANE VERWANDELT !"
7700 PRINT" DESHALB MUESSEN SIE LEIDER AUFGEBEN."
7705 PRINT"[158] MOECHTEN SIE ES NOCH EINMAL PROBIEREN ?"
7710 GETI$:IFI$="J"THENRUN5
7715 IFI$<>"N"THEN7710
7720 END
7799 REM **** GEWONNEN ****
7800 PRINT"[147][158]        ... UND  DER  "H$(5)" ...":FORI=1TO1500:NEXT
7805 PRINT"[145]         ... VERWANDELT  SICH ...":FORI=1TO1500:NEXT
7810 PRINT"[145]... IN EINE WUNDERSCHOENE PRINZESSIN ...":FORI=1TO2000:NEXT
7815 PRINT"[147]":GOTO7840
7820 POKEVI+21,0:PRINT"[147][158]    SIE HABEN DEN ZAUBERER BESIEGT !!!":GOTO7840
7830 PRINT"[147][158]    SIE HABEN DEN SCHATZ GEFUNDEN !!!"
7840 PRINTSPC(13)"GRATULIERE,":PRINT"     SIE HABEN IHR ZIEL ERREICHT !!"
7850 PRINT"      WOLLEN SIE WEITER SPIELEN ?"
7860 GETI$:IFI$="J"THENRUN5
7870 IFI$<>"N"THEN7860
7880 END
8000 DATAOEFFNE,BDJPRU,FANGE,EMO,KUESSE,EMNOU,NIMM,ABCDEFGHIJKLQRU
8005 DATAWIRF,ABCDEFGHIJKL,LIES,DIS,BERUEHRE,PQTU,TOETE,EMNO
8010 DATAZERSTOERE,ABPQRT,WERFE,LESE,KLOPFE,ERSCHLAGE,ZERBRECHE
8015 DATAGLASKUGEL,KAEFIG,AMULETT,BUCH,FROSCH,HELM,KEULE,SCHWERT,ZETTEL,BALL
8020 DATASCHLUESSEL,KETTENHEMD,MONSTER,ZAUBERER,GEIST,TUER,SPIEGEL,SCHRANK
8025 DATASCHRIFT,WAND,QUADRAT
8030 DATAS,03,S-O,0503,W-O,0204,W-H,0311,N-S,0208,O,07,S-W,1006,N-O,0509
8035 DATAS-W-O-R,13081018,N-W,0709,R,04,W-O,0013,N-W-O,091214,W-O,1300,O,16
8040 DATAW-O-H,151713,N-W,1916,H,09,S,17
8045 DATA20,20,20,20,18,2,21,21,21,21,6,5
8050 DATASILBER,BLUME,GOLD,RING,KUPFER,HORN,PLATIN,STERN
8054 REM SPRITE 1 - GEIST
8055 DATA0,127,0,0,255,192,1,206,96,3,255,240,1,255,240,1,245,248,1,255,248
8060 DATA3,255,248,7,255,248,15,255,252,31,255,254,3,255,240,3,255,224
8065 DATA3,255,224,7,255,224,7,255,224,7,255,240,15,255,240,15,255,248
8070 DATA31,255,252,59,187,110
8074 REM SPRITE 2 - MONSTER
8075 DATA12,0,48,30,0,120,3,0,192,1,129,128,3,195,192,15,231,240,62,126,124
8080 DATA124,60,62,248,60,31,254,126,127,255,255,255,127,255,254,127,255,254
8085 DATA63,90,252,30,165,120,31,255,248,7,255,224,4,126,32,4,60,32
8090 DATA31,0,248,42,129,84
8094 REM SPRITE 3 - ZAUBERER
8095 DATA0,15,224,0,63,128,0,127,128,0,219,0,1,255,0,3,255,128,31,255,240
8100 DATA127,255,252,127,255,252,111,255,236,111,255,236,103,255,204,98,170,140
8105 DATA99,255,140,71,255,196,7,199,192,15,131,224,15,1,224,14,0,224
8110 DATA28,0,112,60,0,120
8200 REM
8201 REM **********************
8202 REM *   CASTLE OF DOOM   *
8203 REM * VON B. WEISSBECKER *
8204 REM *  MAERZ/APRIL 1984  *
8205 REM **********************